VB.NET - 文字列の先頭をゼロで埋める(ゼロパディング)

Dim <ゼロパディング結果> As String = <対象文字列>.PadLeft(<桁数>, "0")

Dim before As String = "123"

' 10桁で前ゼロ埋め
Dim after As String = before.PadLeft(10, "0")

' 結果 = "0000000123"
Console.WriteLine(after)

' 結果 = "123"(元の文字列はそのまま)
Console.WriteLine(before)

Dim value As String
Dim result As String

' 結果 = "0+123"
value = "+123"
result = value.PadLeft(5, "0")

' 結果 = "0-123"
value = "-123"
result = value.PadLeft(5, "0")

''' <summary>
''' ゼロパディングを行う
''' </summary>
''' <param name="value">対象文字列</param>
''' <param name="digits">桁数</param>
''' <returns>ゼロパディング後の文字列</returns>
Function ZeroPadding(value As String, digits As Integer) As String
    ' 対象文字列 が Nothing の場合、そのまま返す。
    If value Is Nothing Then
        Return Nothing
    End If

    ' 桁数がマイナスの場合はエラーにする
    If digits < 0 Then
        Throw New ArgumentException("digits は0以上を指定してください。")
    End If

    ' 念のため空白を取り除く
    Dim result As String = value.Trim()

    ' 先頭1文字を取り出す
    Dim sign As String = If(result.Length >= 1, result.Substring(0, 1), String.Empty)

    ' 先頭の文字が符号の場合、処理を分岐
    If sign = "+" OrElse sign = "-" Then
        ' 先頭の符号を取り除く
        result = result.Remove(0, 1)

        ' 指定桁数で前ゼロ埋め
        result = result.PadLeft(digits - 1, "0")

        ' 先頭に符号を付与
        result = sign + result
    Else
        ' 指定桁数で前ゼロ埋め
        result = result.PadLeft(digits, "0")
    End If

    Return result
End Function

Dim result As String

' 結果 = "00000"
result = ZeroPadding("", 5)

' 結果 = "00123"
result = ZeroPadding("123", 5)

' 結果 = "+0123"
result = ZeroPadding("+123", 5)

' 結果 = "-0123"
result = ZeroPadding("-123", 5)